在完成地址無關(guān)fixup后，u-boot開始對一些系統(tǒng)寄存器進(jìn)行初始化。

第一段代碼如下：

pie_fixup_done:
#endif

#ifdef CONFIG_SYS_RESET_SCTRL
    bl reset_sctrl --------------------------------------------------------------------- (1)
#endif

#if defined(CONFIG_ARMV8_SPL_EXCEPTION_VECTORS) || !defined(CONFIG_SPL_BUILD) ---------- (2)
.macro set_vbar, regname, reg
    msr regname, reg
.endm
    adr x0, vectors
#else
.macro set_vbar, regname, reg
.endm
#endif
    /*
     * Could be EL3/EL2/EL1, Initial State:
     * Little Endian, MMU Disabled, i/dCache Disabled
     */
    switch_el x1, 3f, 2f, 1f ---------------------------------------------------------- (3)
3: set_vbar vbar_el3, x0
    mrs x0, scr_el3
    orr x0, x0, #0xf   /* SCR_EL3.NS|IRQ|FIQ|EA */
    msr scr_el3, x0
    msr cptr_el3, xzr   /* Enable FP/SIMD */
    b 0f
2: mrs x1, hcr_el2
    tbnz x1, #34, 1f   /* HCR_EL2.E2H */
    set_vbar vbar_el2, x0
    mov x0, #0x33ff
    msr cptr_el2, x0   /* Enable FP/SIMD */
    b 0f
1: set_vbar vbar_el1, x0
    mov x0, #3 < < 20
    msr cpacr_el1, x0   /* Enable FP/SIMD */
0:

#ifdef COUNTER_FREQUENCY -------------------------------------------------------------- (4)
    branch_if_not_highest_el x0, 4f
    ldr x0, =COUNTER_FREQUENCY
    msr cntfrq_el0, x0   /* Initialize CNTFRQ */
#endif

4: isb ------------------------------------------------------------------------------- (5)

...
...
#ifdef CONFIG_SYS_RESET_SCTRL
reset_sctrl:
    switch_el x1, 3f, 2f, 1f
3:
    mrs x0, sctlr_el3
    b 0f
2:
    mrs x0, sctlr_el2
    b 0f
1:
    mrs x0, sctlr_el1

0:
    ldr x1, =0xfdfffffa
    and x0, x0, x1

    switch_el x1, 6f, 5f, 4f
6:
    msr sctlr_el3, x0
    b 7f
5:
    msr sctlr_el2, x0
    b 7f
4:
    msr sctlr_el1, x0

7:
    dsb sy
    isb
    b __asm_invalidate_tlb_all ----------------------------------------------------- (6)
    ret
#endif

• ? （1）一般情況下此功能不需要使用，但是一些由其他固件引導(dǎo)啟動的u-boot，board希望系統(tǒng)行為能按照自己預(yù)期行為執(zhí)行而不受上一級加載器的影響，所以使用CONFIG_SYS_RESET_SCTRL來決定是否重置系統(tǒng)控制寄存器，包括保證處理器處于小端，關(guān)閉data cache，關(guān)閉mmu。 其中switch_el是一個宏，用于讀取當(dāng)前所處的異常級別，根據(jù)所處異常級別調(diào)用對應(yīng)的系統(tǒng)控制寄存器。某些時候u-boot的加載并不是一定在el3級別，當(dāng)存在atf等時，el3由atf控制，atf會將u-boot的運(yùn)行級別切換到el2，以便保證自己的控制級別，所以u-boot通過switch_el來選擇自己能夠控制的系統(tǒng)寄存器。
• ? （2）定義設(shè)置異常向量表的宏，將異常向量表的地址寫入/reg設(shè)置的系統(tǒng)寄存器即可完成異常向量表的設(shè)置，這里u-boot是需要設(shè)置異常向量表的，而spl默認(rèn)是不需要設(shè)置異常向量表的，畢竟spl只是一個加載器只會運(yùn)行一次，不過當(dāng)定義了CONFIG_ARMV8_SPL_EXCEPTION_VECTORS時可以為spl也設(shè)置一個異常向量表。
• ? （3）同樣的使用switch_el來跳轉(zhuǎn)到對應(yīng)級別的路徑上去執(zhí)行，在進(jìn)行系統(tǒng)寄存器設(shè)置時，因為在這之前已經(jīng)由SYS_RESET_SCTRL或者board自己保證處理器處于小端，mmu關(guān)，i-cache和d-cache處于關(guān)閉狀態(tài)了，所以這里直接進(jìn)行對應(yīng)級別系統(tǒng)寄存器設(shè)置，首先是跳轉(zhuǎn)到對應(yīng)表設(shè)置對應(yīng)級別的異常向量表。接著會有如下三種情況： 當(dāng)處于EL3時，會設(shè)置安全配置系統(tǒng)寄存器（scr_el3），會將低四位bit設(shè)置為0xf，表示設(shè)置處理器處于非安全模式，任何級別的物理irq中斷，物理fiq，異常abort中斷，異常SError中斷都將被路由到el3級別。后續(xù)這些設(shè)置將在啟動Linux時被修改，這些設(shè)置僅用于在u-boot階段。接著將cptr_el3清零，使用xzr是可以快速操作寄存器為零。這里保證任何級別下訪問SIMD和floating-point指令不會導(dǎo)致觸發(fā)異常陷入el3。 當(dāng)處于EL2時，首先根據(jù)HCR_EL2.E2H判斷系統(tǒng)是一個虛擬機(jī)管理器還是主機(jī)系統(tǒng)，當(dāng)E2H = 0時，表示系統(tǒng)處于主機(jī)系統(tǒng)只需要做el3一樣的操作配置SIMD和FP指令不會陷入el2即可。 當(dāng)系統(tǒng)處于EL1時，則什么也不需要操作只需要配置SIMD和FP指令不會陷入el1。
• ? （4）u-boot在啟動時系統(tǒng)的時鐘頻率不一定配置了，所以當(dāng)在include/configs/xxxxxx.h中定義了COUNTER_FREQUENCY的頻率值時，說明需要在此處配置系統(tǒng)時鐘，所以根據(jù)宏 branch_if_not_highest_el判斷當(dāng)系統(tǒng)不處于EL3時則需要設(shè)置系統(tǒng)的時鐘工作頻率cntfrq_el0，后續(xù)Linux或者u-boot根據(jù)讀出的這個值計算出系統(tǒng)每納秒的滴答數(shù)從而供軟件獲取時間流逝值。
• ? （5）isb指令用于確保上述操作指令被正確真正的執(zhí)行了，屬于同步指令的一種。
• ? （6）在進(jìn)行系統(tǒng)控制器復(fù)位時，dsb sy，isb，__asm_invalidate_tlb_all三個操作在這里的意義是，因為對處理器的小端，mmu，d-cache進(jìn)行了復(fù)位，所以這里必須通過dsb和isb確保數(shù)據(jù)和指令全部執(zhí)行和寫入，這里進(jìn)行了mmu和cache關(guān)閉操作，那么如果有緩存的tlb在這個時候這些緩存的tlb數(shù)據(jù)就是無效的，這里對可能緩存的tlb進(jìn)行全部無效化，確保后續(xù)任何可能的mmu開啟操作不會使用到這些無用的tlb條目而導(dǎo)致系統(tǒng)異常。